{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };
  outputs = { self, nixpkgs, ... }: let
    forAllSystems = f: (nixpkgs.lib.genAttrs [ "x86_64-linux" "aarch64-linux" ] (system: let
      pkgs = import nixpkgs { inherit system; };
    in f { inherit pkgs system; } ));
  in {          
    packages = forAllSystems ({ pkgs, system, ... }: {
      mitel-ommclient2 = pkgs.python3Packages.buildPythonPackage {
        pname = "mitel-ommclient2";
        version = "0.0.1";

        src = ./.;

        outputs = [
          "out"
          "doc"
        ];

        nativeBuildInputs = [
          pkgs.python3Packages.sphinxHook
        ];

        format = "pyproject";

        buildInputs = [ pkgs.python3Packages.hatchling ];
        propagatedBuildInputs = [ pkgs.python3Packages.rsa ];

        pythonImportsCheck = [ "mitel_ommclient2" ];
      };
      default = self.packages."${system}".mitel-ommclient2;
    });

    apps = forAllSystems ({ system, ... }: {
      ommclient2 = {
        type = "app";
        program = self.packages.${system}.mitel-ommclient2 + "/bin/ommclient2";
      };
      default = self.apps.${system}.ommclient2;
    });

    hydraJobs = {
      inherit (self)
        packages;
    };
  };
}