{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    flake-utils.url = "github:numtide/flake-utils";

    nix-filter.url = "github:numtide/nix-filter";
  };

  outputs = { self, nixpkgs, flake-utils, nix-filter}: {
    overlays.default = final: prev: {
      asterisk-sounds-de = prev.stdenvNoCC.mkDerivation {
        src = nix-filter.lib {
          root = self;
          exclude = [
            (nix-filter.lib.matchExt "nix")
            "flake.lock"
          ];
        };
        name = "asterisk-sounds-de";
        version = "2.11.19";
        dontBuild = true;
        installPhase = ''
          mkdir $out
          cp -r * $out
        '';
      };
    };
    nixosModules.default = {
      imports = [ ./module.nix ];

      nixpkgs.overlays = [
        self.overlays.default
      ];
    };
  } // (flake-utils.lib.eachDefaultSystem (system:
    let
      pkgs = import nixpkgs { 
        inherit system;
        overlays = [ self.overlays.default ];
      };
    in
    {
      packages = {
        inherit (pkgs) asterisk-sounds-de;
        default = pkgs.asterisk-sounds-de;
      };
    }));
}